AsUnit ist ein Open Source Framework für Modultests (engl. unit test). Mithilfe von Unittests kann man automatisierte Tests in ActionScript durchführen, um Fehler in den eigenen Klassen zu erkennen und Qualitätssicherung zu betreiben.
Mit AsUnit kann z.B. eine Methode einer Klasse überprüfen werden, ob sie die gewünschten Werte zurückgibt. Dies geschieht einfach durch das Kompilieren eines Testprogramms in Flash. Somit kann man jederzeit, z.B. nach einer Änderung des Quellcodes, den Testlauf erneut starten und schauen, ob immer noch alles okay ist. Das spart Zeit (und Nerven).
Im Folgenden eine Einführung, wie AsUnit verwendet wird. Der Download des kompletten Demoprojekts befindet sich am Ende des Beitrags.
Die Klasse, die getestet werden soll
Als Beispiel dient eine einfache ActionScript-Klasse mit dem Namen Calculator. Sie hat eine Funktion addNumbers(a:Number, b:Number), die zwei Zahlen addiert und die Summe zurückgibt. Als zusätzliche Möglichkeit gibt es eine Eigenschaft offset (Defaultwert 0), die zusätzliche zur Summe hinzu addiert wird.
[as]
package {
public class Calculator {
public var offset:Number;
public function Calculator():void {
offset = 0;
}
public function addNumbers(a:Number, b:Number):Number {
return a + b + offset;
}
}
}
[/as]
Unittest erstellen
Als erstes muss man die Unittests erstellen. Diese werden in einer gesonderten Klasse CalculatorTest abgelegt. Sie sieht folgermaßen in diesem Beispiel aus:
[as]
package {
import asunit.framework.TestCase;
public class CalculatorTest extends TestCase {
private var instance:Calculator;
/**
* Constructor
*/
public function CalculatorTest(testMethod:String) {
super(testMethod);
}
/**
* Set up instance to test with
*/
protected override function setUp():void {
instance = new Calculator();
}
/**
* Delete instance used for testing
*/
protected override function tearDown():void {
instance=null;
}
public function testAddNumbers():void {
assertTrue(„Testen von addNumbers mit 10 und 5“, instance.addNumbers(10,5) == 15);
instance.offset = 5;
assertTrue(„Testen von addNumbers mit 10 und 5 (Offset 5)“, instance.addNumbers(10,5) == 20);
}
}
}
[/as]
Interessant sind eigentlich nur die letzten Zeilen.
Die Methode testAddNumbers soll die korrekte Funktionalität der Methode addNumbers überprüfen. Die Zeile assertTrue("Test addNumbers function", instance.addNumbers(10,5) == 15) enthält zum einen Beschreibungstext des Testfalls („Test addNumbers function“). Zum anderen wird mit instance.addNumbers(10,5) die Funktion ausgeführt und mit dem korrekten Ergebnis 15 (== 15) verglichen.
instance ist dabei ein Objekt der Klasse Calculator. Dieses kann man vor einem Test auch abändern (z.B. instance.offset = 5). Nun kann man einen erneuten Test durchführen, bei dem das Ergebnis 20 sein muss.
Unittest der Testsuite hinzufügen
Dieser einzelne Test muss nun einer Testsuite hinzugefügt werden. Die Testsuite enthält enthält alle durchzuführenden Tests. Dazu gibt es eine Klasse AllTests.as. Die Zeile addTest(new CalculatorTest("testAddNumbers")) fügt die zuvor erstellte Funktion testAddNumbers hinzu.
[as]
package {
import asunit.framework.TestSuite;
public class AllTests extends TestSuite {
public function AllTests() {
super();
addTest(new CalculatorTest(„testAddNumbers“));
}
}
}
[/as]
Test starten
Zuletzt muss man nur noch eine neue Flashdatei erstellen. Dieser weist man lediglich als Dokumentenklasse AsUnitTestRunner zu. Mehr ist nicht nötig.
Der Inhalt der Klasse AsUnitTestRunner.as, die im gleichen Verzeichnis wie die .fla liegen muss, lautet:
[as]
package {
import asunit.textui.TestRunner;
public class AsUnitTestRunner extends TestRunner {
public function AsUnitTestRunner() {
start(AllTests, null, TestRunner.SHOW_TRACE);
}
}
}
[/as]
Jetzt kann man mit „Ctrl+Enter“ den Test starten. Der Testlauf läuft fehlerfrei durch:
Ändert man probehalber etwas in der Funktion, damit es nicht mehr korrekt funktioniert, schlägt der Test fehl. Anhand des Fehlertextes sieht man, wo das Problem liegt.
Selbstverständich sollte nicht unerwähnt bleiben, dass Unittest natürlich nicht alle Fehler erkennen können (z.B. Fehler bei der Integration). Auf jeden Fall aber eine sinnvolle Sache.
Download: Quelldateien (.zip) (Demoprojekt)
Link: asunit.org
Link: Unit Testing with AsUnit
[ad]